***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 17, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt 3P0SMCJ26CA 1 2 
.param
+vc0 = 4.302e-11	vc1 = 1.016e-11		vc2 = 2.753e-12	 	vc3 = 2.195e-1
+tc1 = 6.511e-2		tc2 = 3.451e-2		tc3 = 3.421e-2		tc4 = 2.771e-2
d1 1 c zener
g1 c 1 value = {(vc0+vc1*v(c,1))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(c,1))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d2 2 c zener
g2 c 2 value = {(vc0+vc1*v(c,2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(c,2))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1   
***** dc model parameter *****
+ is = 1e-14		   n = 1		  rs = 1e-3
+ibv = 1e-3		 nbv = 1		  bv = 30.35
***** capacitance parameter *****
+cjo = 2.581e-9		   m = 2.872e-1		  vj = 1.072
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.11 		 xti = 3
+trs1 = 1e-4		tbv1 = 5.955e-4		tbv2 = 0.161e-7
.ends 3P0SMCJ26CA
*$
